Cara Mengakses Sensor Suhu dan Kelembaban Menggunakan DHT11 & DHT22 dengan Arduino

Halo sahabat Arduino....

Selamat datang dan selamat kembali lagi di halaman yang membahas seputar teknologi, pemrograman dan elektronika. Pada kali ini saya akan memberikan tutorial cara mengakses Sensor Suhu dan Kelembaban menggunakan DHT11 & DHT22 dengan Arduino. 

Sensor ini sangat populer untuk penggemar elektronik karena harganya murah tetapi tetap memberikan kinerja yang bagus untuk projek suhu dan kelembapan. 

Berikut adalah spesifikasi dan perbedaan utama antara DHT11 & DHT22:

DHT22 adalah versi yang lebih mahal dan tentu sudah jelas memiliki spesifikasi yang lebih baik. Rentang pengukuran suhu adalah dari -40 hingga +125 derajat Celcius dengan akurasi + -0,5 derajat, sedangkan rentang suhu DHT11 adalah dari 0 hingga 50 derajat Celcius dengan akurasi +-2 derajat. Sensor DHT22 juga memiliki rentang pengukuran kelembaban yang lebih baik, dari 0 hingga 100% dengan akurasi 2-5%, sedangkan rentang kelembaban DHT11 adalah dari 20 hingga 80% dengan akurasi 5:

KOMPONEN
1. Arduino UNO (bisa diganti dengan type lain)
2. DHT11 / DHT22
3. Resistor 5K / 10K

SKEMATIK
Rangkailah semua komponen seperti gambar berikut:

SOURCE CODE

Sebelum memasukkan code kadalam Arduino, terlebih dahulu masukkan Library Temp & Humidity Sensors yang bisa di download DISINI...!

Setelah di download, kemudian ektrak file dan masukkan kedalam library arduino: C:\Program Files (x86)\Arduino\libraries

#include "DHT.h"

#define DHTPIN 2     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 3 (on the right) of the sensor to GROUND (if your sensor has 3 pins)
// Connect pin 4 (on the right) of the sensor to GROUND and leave the pin 3 EMPTY (if your sensor has 4 pins)
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}

Selesai di Upload, bukalah serial monitor dan setting beud rate pada 9600.

SELAMAT BERKARYA...!